This post originated from an RSS feed registered with Agile Buzz by James Robertson. Original Post: Andale! Andale! Yeehaw! Feed Title: Travis Griggs - Blog Feed URL: http://www.cincomsmalltalk.com/rssBlog/travis-rss.xml Feed Description: This TAG Line is Extra Latest Agile Buzz Posts Latest Agile Buzz Posts by James Robertson Latest Posts From Travis Griggs - Blog

A colleague refactored some code the other day. And our tests broke of course. So it was time to fix them. One of the harder scenarios to test is objects which move from state to state by some other process. Usually, I like test driven design for this, because it usually results in a design where the state changes are message sends and the process that actually triggers them is dumbed down to something simple like:

[self tick] repeat

What if I could change time for the process? What if I could change my mind and tell it something like "I know you're waiting for something, but let's just skip that this time and get right down to business, OK?" What I really need, is a way to tell a process to un-delay itself. Can we do that? Sure, this is Smalltalk. :)

Process>'>unDelay
	suspendedContext ifNotNil: 
			[:sc | 
			sc sender ifNotNil: 
					[:sender | 
					(sender receiver isKindOf: Delay) 
						ifTrue: [(sc receiver isKindOf: Semaphore) ifTrue: [sc receiver signal]]]]

Basically this checks a process to see if it is suspended. It then determines by examining the message send history if it is waiting on a Semaphore, and if that Semaphore was put in place by a Delay. If so, it's just a simple matter of signalling the Semaphore. Cool, huh? Oh, the nifty things you can do with messages.

So this is handy for testing, but can we test it? Sure, why not. First of all, we have a simple test:

testUndelay
	| proc |
	touched := false.
	proc := 
			[(Delay forSeconds: 1000) wait.
			touched := true] fork.
	
	[proc unDelay.
	self deny: touched.
	Processor activeProcess yield.
	proc unDelay.
	Processor activeProcess yield.
	self assert: touched] 
			ensure: [proc terminate]

We can put together some edge case tests too:

testUndelayWhenBlockedByNonDelay
	| proc untouched sem |
	untouched := true.
	sem := Semaphore new.
	proc := 
			[sem wait.
			untouched := false] 
					forkAt: Processor activeProcess priority - 1.
	
	[proc unDelay.
	self assert: untouched.
	(Delay forSeconds: 0.1) wait.
	proc unDelay.
	self assert: untouched] 
			ensure: [proc terminate]

testUndelayWhenNoDelay
	| proc |
	proc := [Time waste: 10000] forkAt: Processor activeProcess priority - 1.
	
	[proc unDelay.
	(Delay forSeconds: 0.1) wait.
	proc unDelay] 
			ensure: [proc terminate]

Sidenote: I was disappointed to learn that Speedy Gonzales has been banished from just about any mainstream TV in the US. Apparently, he was racist. I guess I can dump my childhood reinforced baggage that my south-of-the-border cousins are smarter than me and my fellow cats. Sigh.